Tutorial Arduino Untuk Pemula : Membuat blink tanpa delay pada arduino

Pada pembahasan kali ini saya akan membahas tentang cara mebuat blink tanpa delay pada arduino. untuk mebuat blink led tanpa delay mebutuhkan led sebagai output.

adapun syntax arduinonya adalah :

/* Blink without Delay

 Turns on and off a light emitting diode(LED) connected to a digital
 pin, without using the delay() function.  This means that other code
 can run at the same time without being interrupted by the LED code.

 The circuit:
 * LED attached from pin 13 to ground.
 * Note: on most Arduinos, there is already an LED on the board
 that's attached to pin 13, so no hardware is needed for this example.


 created 2005
 by David A. Mellis
 modified 8 Feb 2010
 by Paul Stoffregen

 This example code is in the public domain.


 http://www.arduino.cc/en/Tutorial/BlinkWithoutDelay
 */

// constants won't change. Used here to
// set pin numbers:
const int ledPin =  13;      // the number of the LED pin

// Variables will change:
int ledState = LOW;             // ledState used to set the LED
long previousMillis = 0;        // will store last time LED was updated

// the follow variables is a long because the time, measured in miliseconds,
// will quickly become a bigger number than can be stored in an int.
long interval = 1000;           // interval at which to blink (milliseconds)

void setup() {
  // set the digital pin as output:
  pinMode(ledPin, OUTPUT);    
}

void loop()
{
  // here is where you'd put code that needs to be running all the time.

  // check to see if it's time to blink the LED; that is, if the
  // difference between the current time and last time you blinked
  // the LED is bigger than the interval at which you want to
  // blink the LED.
  unsigned long currentMillis = millis();

  if(currentMillis - previousMillis > interval) {
    // save the last time you blinked the LED
    previousMillis = currentMillis;  

    // if the LED is off turn it on and vice-versa:
    if (ledState == LOW)
      ledState = HIGH;
    else
      ledState = LOW;

    // set the LED with the ledState of the variable:
    digitalWrite(ledPin, ledState);
  }
}

Sekian pembahasan dari saya terimakasih.

Sumber :  http://www.arduino.cc/en/Tutorial/BlinkWithoutDelay

Baca selengkapnya »

Tutorial arduino untuk pemula : Cara menggunakan sensor ping (ultrasonik)

Pada pembahasan kali ini akan embahas tentang cara menggunakan sensor ping (ultrasonik) pada arduino. ultrasonik merupakan sensor jarak yang berfungsi untuk mengukur jarak.

adapun contoh syntaxnya adalah :

/* Ping))) Sensor
 
   This sketch reads a PING))) ultrasonic rangefinder and returns the
   distance to the closest object in range. To do this, it sends a pulse
   to the sensor to initiate a reading, then listens for a pulse
   to return.  The length of the returning pulse is proportional to
   the distance of the object from the sensor.
   
   The circuit:
* +V connection of the PING))) attached to +5V
* GND connection of the PING))) attached to ground
* SIG connection of the PING))) attached to digital pin 7

   http://www.arduino.cc/en/Tutorial/Ping
 
   created 3 Nov 2008
   by David A. Mellis
   modified 30 Aug 2011
   by Tom Igoe

   This example code is in the public domain.

 */

// this constant won't change.  It's the pin number
// of the sensor's output:
const int pingPin = 7;

void setup() {
  // initialize serial communication:
  Serial.begin(9600);
}

void loop()
{
  // establish variables for duration of the ping,
  // and the distance result in inches and centimeters:
  long duration, inches, cm;

  // The PING))) is triggered by a HIGH pulse of 2 or more microseconds.
  // Give a short LOW pulse beforehand to ensure a clean HIGH pulse:
  pinMode(pingPin, OUTPUT);
  digitalWrite(pingPin, LOW);
  delayMicroseconds(2);
  digitalWrite(pingPin, HIGH);
  delayMicroseconds(5);
  digitalWrite(pingPin, LOW);

  // The same pin is used to read the signal from the PING))): a HIGH
  // pulse whose duration is the time (in microseconds) from the sending
  // of the ping to the reception of its echo off of an object.
  pinMode(pingPin, INPUT);
  duration = pulseIn(pingPin, HIGH);

  // convert the time into a distance
  inches = microsecondsToInches(duration);
  cm = microsecondsToCentimeters(duration);
 
  Serial.print(inches);
  Serial.print("in, ");
  Serial.print(cm);
  Serial.print("cm");
  Serial.println();
 
  delay(100);
}

long microsecondsToInches(long microseconds)
{
  // According to Parallax's datasheet for the PING))), there are
  // 73.746 microseconds per inch (i.e. sound travels at 1130 feet per
  // second).  This gives the distance travelled by the ping, outbound
  // and return, so we divide by 2 to get the distance of the obstacle.
  // See: http://www.parallax.com/dl/docs/prod/acc/28015-PING-v1.3.pdf
  return microseconds / 74 / 2;
}

long microsecondsToCentimeters(long microseconds)
{
  // The speed of sound is 340 m/s or 29 microseconds per centimeter.
  // The ping travels out and back, so to find the distance of the
  // object we take half of the distance travelled.
  return microseconds / 29 / 2;
}

Sekian pembahasan dari saya, terima kasih.

Sumber : http://www.arduino.cc/en/Tutorial/Ping

Baca selengkapnya »

Tutorial Arduino Untuk Pemula : Penggunaan Motor Servo Pada Arduino

Pada pembahasan kali ini saya akan membahas tentang oenggunaan motor servo pada arduino. adapun kegunaan motor servo sangan bermanfaat untuk robot lengan dan sebagainya karena torsinya besar.

adapun contoh syntax motor servo pada arduino :

 // Controlling a servo position using a potentiometer (variable resistor)
// by Michal Rinott <http://people.interaction-ivrea.it/m.rinott>

#include <Servo.h>

Servo myservo;  // create servo object to control a servo

int potpin = 0;  // analog pin used to connect the potentiometer
int val;    // variable to read the value from the analog pin

void setup()
{
  myservo.attach(9);  // attaches the servo on pin 9 to the servo object
}

void loop()
{
  val = analogRead(potpin);            // reads the value of the potentiometer (value between 0 and 1023)
  val = map(val, 0, 1023, 0, 179);     // scale it to use it with the servo (value between 0 and 180)
  myservo.write(val);                  // sets the servo position according to the scaled value
  delay(15);                           // waits for the servo to get there
}

Sekian pembahasan dari saya. terima kasih

Sumber : http://people.interaction-ivrea.it/m.rinott

Baca selengkapnya »

Tutorial Arduino Untuk Pemula : Kondisi perulangan while pada arduino

Pada kesempatan kali ini saya akan membahas tentang cara menggunakan perulangan while pada arduino. adapun while do merupakan sebuah perulagan yang dapat dimanfaatkan untuk melakukan perulangan yang sudah diketahui kondisi dimana harus berulang.

adapun contoh syntax arduinonya adalah :

/*
  Conditionals - while statement

 This example demonstrates the use of  while() statements.

 While the pushbutton is pressed, the sketch runs the calibration routine.
 The  sensor readings during the while loop define the minimum and maximum
 of expected values from the photo resistor.

 This is a variation on the calibrate example.

 The circuit:
 * photo resistor connected from +5V to analog in pin 0
 * 10K resistor connected from ground to analog in pin 0
 * LED connected from digital pin 9 to ground through 220 ohm resistor
 * pushbutton attached from pin 2 to +5V
 * 10K resistor attached from pin 2 to ground

 created 17 Jan 2009
 modified 30 Aug 2011
 by Tom Igoe

 This example code is in the public domain.

 http://arduino.cc/en/Tutorial/WhileLoop

 */


// These constants won't change:
const int sensorPin = A2;       // pin that the sensor is attached to
const int ledPin = 9;           // pin that the LED is attached to
const int indicatorLedPin = 13; // pin that the built-in LED is attached to
const int buttonPin = 2;        // pin that the button is attached to


// These variables will change:
int sensorMin = 1023;  // minimum sensor value
int sensorMax = 0;     // maximum sensor value
int sensorValue = 0;         // the sensor value


void setup() {
  // set the LED pins as outputs and the switch pin as input:
  pinMode(indicatorLedPin, OUTPUT);
  pinMode (ledPin, OUTPUT);
  pinMode (buttonPin, INPUT);
}

void loop() {
  // while the button is pressed, take calibration readings:
  while (digitalRead(buttonPin) == HIGH) {
    calibrate();
  }
  // signal the end of the calibration period
  digitalWrite(indicatorLedPin, LOW);

  // read the sensor:
  sensorValue = analogRead(sensorPin);

  // apply the calibration to the sensor reading
  sensorValue = map(sensorValue, sensorMin, sensorMax, 0, 255);

  // in case the sensor value is outside the range seen during calibration
  sensorValue = constrain(sensorValue, 0, 255);

  // fade the LED using the calibrated value:
  analogWrite(ledPin, sensorValue);
}

void calibrate() {
  // turn on the indicator LED to indicate that calibration is happening:
  digitalWrite(indicatorLedPin, HIGH);
  // read the sensor:
  sensorValue = analogRead(sensorPin);

  // record the maximum sensor value
  if (sensorValue > sensorMax) {
    sensorMax = sensorValue;
  }

  // record the minimum sensor value
  if (sensorValue < sensorMin) {
    sensorMin = sensorValue;
  }
}

Sekian pembahasan dari saya Terima kasih.

Sumber : http://arduino.cc/en/Tutorial/WhileLoop

Baca selengkapnya »

Tutorial arduino untuk pemula : Kondisi perulangan for loop pada arduino

Pada kesempatan kali ini saya akan membahas tentang perulangan for loop pada arduino. perulangan for loop pada arduino berfungsi untuk melakukan counter. dibawah akan diberikan contoh penggunaan for loop pada arduino.

adapun syntax arduinonya adalah :
/*
  For Loop Iteration

 Demonstrates the use of a for() loop.
 Lights multiple LEDs in sequence, then in reverse.

 The circuit:
 * LEDs from pins 2 through 7 to ground

 created 2006
 by David A. Mellis
 modified 30 Aug 2011
 by Tom Igoe

This example code is in the public domain.

 http://www.arduino.cc/en/Tutorial/ForLoop
 */

int timer = 100;           // The higher the number, the slower the timing.

void setup() {
  // use a for loop to initialize each pin as an output:
  for (int thisPin = 2; thisPin < 8; thisPin++)  {
    pinMode(thisPin, OUTPUT);    
  }
}

void loop() {
  // loop from the lowest pin to the highest:
  for (int thisPin = 2; thisPin < 8; thisPin++) {
    // turn the pin on:
    digitalWrite(thisPin, HIGH);  
    delay(timer);                
    // turn the pin off:
    digitalWrite(thisPin, LOW);  
  }

  // loop from the highest pin to the lowest:
  for (int thisPin = 7; thisPin >= 2; thisPin--) {
    // turn the pin on:
    digitalWrite(thisPin, HIGH);
    delay(timer);
    // turn the pin off:
    digitalWrite(thisPin, LOW);
  }
}

sekian pembahasan dari saya terima kasih.

Sumber : http://www.arduino.cc/en/Tutorial/ForLoop

Baca selengkapnya »

Tutorial Arduino untuk pemula : Kondisi IF pada arduino

Pada kesempatan kali ini saya akan membahas tentang penggunaan IF pada arduino. adapun untuk lebeih jelasnya dapat dilihat pada perintah program yang akan dijelaskan dibawah ini.

Adapun syntax arduinonya adalah :

/*
  Conditionals - If statement

 This example demonstrates the use of if() statements.
 It reads the state of a potentiometer (an analog input) and turns on an LED
 only if the LED goes above a certain threshold level. It prints the analog value
 regardless of the level.

 The circuit:
 * potentiometer connected to analog pin 0.
 Center pin of the potentiometer goes to the analog pin.
 side pins of the potentiometer go to +5V and ground
 * LED connected from digital pin 13 to ground

 * Note: On most Arduino boards, there is already an LED on the board
 connected to pin 13, so you don't need any extra components for this example.

 created 17 Jan 2009
 modified 9 Apr 2012
 by Tom Igoe

This example code is in the public domain.

http://arduino.cc/en/Tutorial/IfStatement

 */

// These constants won't change:
const int analogPin = A0;    // pin that the sensor is attached to
const int ledPin = 13;       // pin that the LED is attached to
const int threshold = 400;   // an arbitrary threshold level that's in the range of the analog input

void setup() {
  // initialize the LED pin as an output:
  pinMode(ledPin, OUTPUT);
  // initialize serial communications:
  Serial.begin(9600);
}

void loop() {
  // read the value of the potentiometer:
  int analogValue = analogRead(analogPin);

  // if the analog value is high enough, turn on the LED:
  if (analogValue > threshold) {
    digitalWrite(ledPin, HIGH);
  }
  else {
    digitalWrite(ledPin,LOW);
  }

  // print the analog value:
  Serial.println(analogValue);
  delay(1);        // delay in between reads for stability
}

Sekian pembahasan dari saya terima kasih.

Sumber : http://arduino.cc/en/Tutorial/IfStatement

Baca selengkapnya »

Tutorial Arduino Untuk Pemula : Cara Menggunaka Liquid Crystal Display pada arduino

Pada kesempatan kali ini saya akan membahas mengenai cara menggunaka LCD pada arduino. adapun komponen yang diperlukan adalah sebuah module LCD dan Arduino uno. untuk pemasangan portnya dapat melihat pada syntax dibawah.

adapun syntax yang dapat digunakan adalah :

Baca selengkapnya »

Tutorial Arduino Untuk Pemula : IR Receive pada arduino

Pada pembahasan kali ini saya akan membahas tentang cara menrima kode hexa dari sebuah perangkat yang mengirimkan data hexa menggunakan inframerah. adapun perangkat yang diperlukan adalah sensor inframerah dan arduino UNO R3.

Baca selengkapnya »

Tutorial Arduino untuk pemula : Cara Melakukan IR Send pada arduino

Pada kesempatan kali ini saya akan mebahas bagaimana melakukan ir Send pada arduino
berikut adalah syntax yang dapat digunakan untuk melakukan ir send

Baca selengkapnya »

Tutorial Arduino Untuk Pemula : Cara melakukan pembacaan data digital dan analog

Arduino merupakan sebuah minsys yang memanfaatkan IC ATMEGA328. Arduino merupakan sebuah mikrokontroller yang mudah dimengerti bagi pemrogram yang sudah menguasai bahasa c.

pada kesempatan kali ini saya akan membahas tentang cara melakukan analogread dan digital read.

Baca selengkapnya »